Inportering af mange lignende tekst filer

Du kan skrive det i VBScript, gemme det i en *.vbs-fil, og køre den med Opgavestyring.

Jeg har selv lavet noget tilsvarende før.

Et spor:

Dim objFSO, objFolder, objFile
Set objFSO = CreateObject("Scripting.FilesystemObject")
Set objFolder = objFSO.GetFolder("c:\ftp")

for each objFile in objFolder.Files
  'blabla.
next

Set objFSO = nothing
Set objFolder = nothing

Siger det dig noget :o)

Hm,,,,, neh, er det en "Step by step" guide et eller andet sted?

Nej, men der er en masse kode i det hvis du ikke har forstand på VBScript og ADO

Men her demonstrerer jeg at du faktisk kan få indholdet ud (med en MessageBox) hvorefter filen kopieres (og overskriver en evt eksisterende fil af samme navn), og slettes

Dim objFSO, objFolder, objFile, strExt, strFilecontent
Set objFSO = CreateObject("Scripting.FilesystemObject")
Set objFolder = objFSO.GetFolder("f:\ftp")

for each objFile in objFolder.Files
    strExt = Split(objFile.Name, ".")(1)
    if Lcase(strExt) = "txt" then
        strFilecontent = objFile.OpenAsTextStream.ReadAll()
        objFile.Copy "f:\ftp\Indlæst\", True
        objFile.Delete
        MsgBox (strFilecontent)
    end if
next

Set objFSO = nothing
Set objFolder = nothing

Hvis du giver mig følgende:
Stien til din Access database, incl. filnavnet
Navnet på tabellen og de kolonner der skal sættes ind i

- så vil jeg gerne lave det til dig

Access database - c:\ftp\database.mdb
Tablenavn - table
kolonnenavn - location, timedate, number, picture

Altså linie1 i tekstfilen skal være i location
linie2 timdate osv....

ok

Hvad med datatyperne på kolonnerne? tekst dato tal eller hvad?

Og hvis der er en dato i teksten, hvilket format kommer den i?

Jge går straks igang

alle er tekst

tak

OK

Hvad er Tabellens Primær nøgle?

Og så er det en dum ide at kalde tabellen for "Table", da det er et reserveret ord, kan du omdøbe den?

Husk at tænke på max længde af felterne, ikke?

logtable heder den nu
ID (autonr) er primkr nøgle

Dim objFSO, objFolder, objFile, strExt, strFilecontent, arrFilecontent
Set objFSO = CreateObject("Scripting.FilesystemObject")
Set objFolder = objFSO.GetFolder("C:\ftp")


Dim Con, Com, Rec, ConnectionString

ConnectionString = "DRIVER=Microsoft Access Driver (*.mdb);UID=admin;UserCommitSync=Yes;Threads=3;SafeTransactions=0;PageTimeout=5;MaxScanRows=8;MaxBufferSize=2048;FIL=MS Access;DriverId=25;DefaultDir=C:\ftp;DBQ=C:\ftp\database.mdb"

Set Con = CreateObject("ADODB.Connection")
Set Com = CreateObject("ADODB.Command")
Set Rec = CreateObject("ADODB.Recordset")

Con.Open ConnectionString
Com.ActiveConnection = Con
Com.CommandText = "SELECT top 1 location, timedate, number, picture FROM logtable WHERE ID = 0"
Rec.Open Com, , 3, 3

on error resume next

for each objFile in objFolder.Files
    strExt = Split(objFile.Name, ".")(1)
    if Lcase(strExt) = "txt" then
        strFilecontent = objFile.OpenAsTextStream.ReadAll()
        arrFilecontent = Split(strFilecontent, VbCrLf)
    Rec.AddNew
    Rec("location") = arrFilecontent(0)
    Rec("timedate") = arrFilecontent(1)
    Rec("number") = arrFilecontent(2)
    Rec("picture") = arrFilecontent(3)
    Rec.Update
    if Con.Errors.Count = 0 and Err.Number = 0 then
        objFile.Copy "C:\ftp\Indlæst\", True
            objFile.Delete
    else
        Rec.Delete
        Rec.Update
        Con.Errors.Clear
        Err.Clear
    end if
   
    end if
next

Rec.Close
Con.Close

Set objFSO = nothing
Set objFolder = nothing
Set Con = nothing
Set Com = nothing
Set Rec = nothing

Det skulle være det

Det skal gemmes som en tekstfil med extension vbs

Jeg flytter filerne til c:\ftp\Indlæst, så den skal være der

Den springer filer over hvis den ikke kan håndtere dem. Der skal stå noget på alle linier i filen, er det OK?

Rettelse:

"Der skal stå noget på alle linier i filen, er det OK?"

Nej, det var fordi jeg ikke havde sat TilladNulllængde til Ja i min Access. Gør det, og den vil betragte en tom linie som en gyldig linie, og lade det tilsvarende felt være tomt

Og så: Dobbeltklik på den, og se hvad der sker :o)

Til slut skal du have den til at køre automatisk, og det gøres via Sceduled Tasks (Eller Opgavestyring eller Planlagte opgaver, afhængig af windows versionen)

Lad mig nu vide hvis du har problemer, så skal jeg hjælpe med fejlfindingen. Jeg kan da dårligt forestille mig at det virker i første forsøg.

Idanielsen, TAK TAK, det virker!!
Kom med et svar så får du velfortjent belønning.

Jo tak :o)

Men nu skal du lige sørge for at teste meget grundigt, for der må vel helst ikke gå noget galt?

Og så skulle du måske selv lære lidt VBScript/VisualBasic/VBA, for det er meget relevant hvis man arbejder med Access, eller andre dele af Office.

Og VBScript er desuden det sprog man bruger når man laver ASP

Jo tak, jeg kunne også forså det meste af det du har lavet.