lave en tæller der kun kan ses af mig

OK, here we go...

Det her har jeg haft liggende længe og ja, det kan du jo ligeså godt bruge... du bruger mySQL og det er jo fint nok, mit er til MS ACCESS men da det kun er din "Connection" der skal laves om så burde der ikke være nogle problemer.

Scriptet består af to filer. Den første er default.asp og indeholder kun scriptet for at opsamle data - koden er kommenteret, så der burde ikke være det vilde der.

filen default.asp:
----------------------------------------------------------------------------
<%
Response.Expires = 0

'Database forbindelse.
'Jeg har her brug access, men der er ingen hindring for,
'at en MySQL database ikke skulle virke.
set conn = Server.CreateObject("ADODB.Connection")
conn.Open "Driver={Microsoft Access Driver (*.mdb)}; DBQ=I:\Webs\Techs\Simple\counter2\db\mydb.mdb"

'Hent den "fremmedes" ip
rem_ip = Request.ServerVariables("REMOTE_ADDR")

'Den ip som ikke skal tælles op i databasen
noCount_ip = "127.0.0.1"


'Her kontrollerer vi så, om rem_ip er den som ikke skal tælles med
if not rem_ip = noCount_ip then

    'Check om Sessionvariablen "nyBruger" er tom
    if IsEmpty(Session("nyBruger")) then
   
        'Hvis den er tom, så giv den en værdi og opret SQL-sætning
        'bemærk, at intUnik = 1 fordi det er en unik bruger
        Session("nyBruger") = 1
       
        SQL = "INSERT INTO stats (strIP, intUnik) VALUES ('" & rem_ip & "', 1)"
   
    else
   
        'Hvis den ikke er tom, så skal den ikke angives en værdi
        'bemærk, at intUnik = 0 fordi det er en bruger der har været her før
        SQL = "INSERT INTO stats (strIP, intUnik) VALUES ('" & rem_ip & "', 0)"
   
    end if
   
    'Der skal under alle omstændigheder indsættes data i databasen,
    'og dette gør vi her
    conn.Execute(SQL)
end if 'IP Check
%>

----------------------------------------------------------------------------

Den anden fil er status.asp og indeholder kode til at vise meget simpel statistik over de indsamlede data. faktisk viser den kun antal unikke brugere, antal brugere i alt og så regner den gennemsnittet ud af sidevisninger pr. brugere

filen status.asp
----------------------------------------------------------------------------
<%
Response.Expires = 0

'Database forbindelse.
'Jeg har her brug access, men der er ingen hindring for,
'at en MySQL database ikke skulle virke.
set conn = Server.CreateObject("ADODB.Connection")
conn.Open "Driver={Microsoft Access Driver (*.mdb)}; DBQ=I:\Webs\Techs\Simple\counter2\db\mydb.mdb"

'Hent diverse ting ud fra databasen
'Først hentes antallet af unikke sidevisninger, intUnik = 1
SQL = "SELECT COUNT(id) as [antal] FROM stats WHERE intUnik = 1"
set oRs = conn.Execute(SQL)

'Variablen intUnik angiver antallet af
'unikke brugere
intUnik = oRs("antal")


'Så skal det samlede antal sidevisninger hentes
SQL = "SELECT COUNT(id) as [total] FROM stats"
set oRs = conn.Execute(SQL)

'Variablen intTotal indeholder totale sidevisninger
intTotal = oRs("total")

'Her udskrives lidt statistik omkring de brugere der har
'brugt sitet, bl.a. sidevisninger pr. bruger
Response.Write("Unikke: " & intUnik)
Response.Write("<br>")
Response.Write("Totale: " & intTotal)
Response.Write("<br>")
Response.Write("Gennemsnitlige sidevisninger pr. bruger: " & Round(intTotal / intUnik, 2))

%>
----------------------------------------------------------------------------

Håber du kan bruge det til noget :)

Casper

mange tak for din kode - jeg er ved at få den til at virke, men jeg er ikke den store ekspert i oprettelse af databaser osv... når læser det her, så må du meget gerne skære det mere ud i pap :P