Sum af en column

her noget kode du kan putte ind i et felt eller "beregnet tekst" (computed text)

_path := "";
_view := "navnetpåviewet";
_column := <kolonnenummeret>;
_lookup := @DbColumn( "":"NoCache"; _path; _view; _column);
_sum := @Sum(_lookup);
@If(@IsError(_lookup); @Text(_lookup); @IsError(_sum); @Text(_sum); _sum)

_path = "" angiver samme database som du er i.
Hvis du vil slå op i en anden database (evt. på en anden server) er syntaksen
_path = "servernavn" : "databasefilsti"
Bemærk at Domino servere via HTTP kun må slå op lokalt (servernavn = "")

Tak for det hurtige svar.  :)

Jeg for en fejl som ser sådan her ud:
Incorrect datatype for database function

Den Column jeg skal have en sum er bliver lavet sådan her:
temp := (@Date(tildag) - @Date(fradag)) / 86400;
weekend_days := @Integer((temp / 7)) * 2;
wkday := @Weekday(fradag);
adjust := @If(((wkday + @Modulo(temp; 7) - 7) > 0); 2; 0);
working_days := temp - (weekend_days + adjust);
@If(fradag = ""; "0"; @If(working_days < 1; "0"; working_days))

Du prøver at summe tal og bogstaver sammen:
  @If(fradag = ""; "0"; @If(working_days < 1; "0"; working_days))
Det er "0" som skal være 0
skal ændres til
  @If(fradag = ""; 0; @If(working_days < 1; 0; working_days))

Alternativt kan du lave
_numbers := @TextToNumber(@Trim(@Text(_lookup)));
_sum := @Sum(_numbers);
Du kan evt. også erstatte 0 med "" (blank) og så få ovenstående @trim til at filtrere de blanke ud inden du summer.
//Jörg

Hvis nu at View'et er tom. Kommer den med en error. Kan man gøre noget ved det?

Hvilken fejlbesked får du?
Du kan ændre
  @If(@IsError(_lookup); @Text(_lookup); @IsError(_sum); @Text(_sum); _sum)
til at samle flere fejlsituationer op.
Når viewet er tomt, så er _lookup = "" (tror jeg). Det kan du passende teste på inden du tester på @IsError(_sum)

  @If(@IsError(_lookup); @Text(_lookup); _lookup = ""; "din fejlbesked"; @IsError(_sum); @Text(_sum); _sum)

Mange tak igen. :)

Det er rigtigt at _lookup = "" når view'et er tomt.

Tak for hjælpen. :)