Print fra stringgrid

Jeg bruger denne og den virker fint. Jeg har dog ikke så store antal rows, som du har.
Prøv den.

procedure PrintStringGrid(Source: TStringGrid; MarginsMM: TRect);

implementation
uses Classes, Printers;

procedure PrintStringGrid(Source: TStringGrid; MarginsMM: TRect);
{todo: gestire gli header (righe Fixed) in modo che siano bold}
{todo: gestire gli header (righe Fixed) in modo che siano ripetuti sulle
pagine successive alla prima}
var ColW: array of integer;      // ampiezza colonne (unità stampante)
    NewPageCols: array of integer;// colonna da cui iniziare nuova pagina
    PrintableRect: TRect;        // area da stampare
    VPos,                        // posizione verticale corrente e
    LineH: integer;              // altezza linea
    VertPageCount: integer;      // num. pagine necessarie per 1 riga

  procedure InitLocalVars;
  const
    teststr = ' abcdef ghijklm opqrst uvwxyz 012 3456 789 ';
  var i: integer;
      lp: integer;
      scrwid, prtwid: integer;
  begin
    // Inizializza area stampabile, posizione verticale
    PrintableRect := Printer.Canvas.ClipRect;
    PrintableRect.Left := PrintableRect.Left +
      MulDiv(MarginsMM.Left * GetDeviceCaps(Printer.Canvas.Handle,
LOGPIXELSX), 10, 254);
    PrintableRect.Right := PrintableRect.Right -
      MulDiv(MarginsMM.Right * GetDeviceCaps(Printer.Canvas.Handle,
LOGPIXELSX), 10, 254);
    PrintableRect.Top := PrintableRect.Top +
      MulDiv(MarginsMM.Top * GetDeviceCaps(Printer.Canvas.Handle,
LOGPIXELSY), 10, 254);
    PrintableRect.Bottom := PrintableRect.Bottom -
      MulDiv(MarginsMM.Bottom * GetDeviceCaps(Printer.Canvas.Handle,
LOGPIXELSY), 10, 254);
    LineH := MulDiv(Printer.Canvas.TextHeight(teststr), 112, 100);
    VPos := PrintableRect.Top + LineH;
    // Calcola larghezza colonne
    scrWid := Source.Canvas.TextWidth(teststr);
    prtWid := Printer.Canvas.TextWidth(teststr);
    SetLength(ColW, Source.ColCount);
    for i := 0 to High(ColW) do
      ColW[i] := MulDiv(Source.ColWidths[i], prtWid, scrWid);
    // Calcola numero pagine necessarie alla stampa in orizzontale
    {todo: gestire le colonne Fixed in modo che le stampi anche sulle pagine
successive}
    VertPageCount := 1;
    lp := PrintableRect.Left;
    SetLength(NewPageCols, VertPageCount);
    NewPageCols[High(NewPageCols)] := Source.ColCount;
    for i := 0 to High(ColW) do begin
      if lp + ColW[i] > PrintableRect.Right then begin
        inc(VertPageCount);
        lp := PrintableRect.Left;
        NewPageCols[High(NewPageCols)] := i;
        SetLength(NewPageCols, VertPageCount);
        NewPageCols[High(NewPageCols)] := Source.ColCount;
      end
      else
        lp := lp + ColW[i];
    end;
  end;

  procedure PrintRow(index: integer; VertPage: integer);
  {todo: allineamento a sx per testo, a dx per numeri:
    serve probabilmente una proprietà associata alle colonne di Source}
  var FirstCol: integer;
      c: integer;
      r: TRect;
  begin
    FirstCol := 0;
    if VertPage > 0 then
      FirstCol := NewPageCols[VertPage - 1];
    r := Rect(PrintableRect.Left, VPos, PrintableRect.Left, VPos + LineH);
    for c := FirstCol to NewPageCols[VertPage]-1 do begin
      r.Right := r.Left + ColW[c];
      DrawText(Printer.Canvas.Handle, PChar(Source.Cells[c, index]), -1, r,
        DT_VCENTER + DT_SINGLELINE + DT_RIGHT);
      r.Left := r.Right;
    end;
    VPos := VPos + LineH;
    if VPos > PrintableRect.Bottom then begin
      Printer.NewPage;
      VPos := PrintableRect.Top + LineH;
    end;
  end;

  procedure FinitLocalVars;
  begin
    Finalize(ColW);
    Finalize(NewPageCols);
  end;

var vp, r: integer;
begin
  Printer.BeginDoc;
  try
    InitLocalVars;
    try
      for vp := 0 to VertPageCount-1 do begin
        if vp > 0 then begin
          Printer.NewPage;
          VPos := PrintableRect.Top + LineH;
        end;
        { PrintColHeaders here }
        for r := 0 to Pred(Source.RowCount) do
          PrintRow(r, vp);
      end;
    finally
      FinitLocalVars;
    end;
  finally
    Printer.EndDoc;
  end;
end;

end.

Skulle du ikke lukke spørgsmålet??

Hvad med at få spørgsmålet lukket?