Overførsel af parameter fra Excel til Access

Her er et eksempel du kan arbejde videre med:

Sub RunParamQuery()
    Dim cnn As ADODB.Connection
    Dim cmd As ADODB.Command
    Dim rst As ADODB.Recordset
    Dim fld As ADODB.Field
   
    ' Åbn Connection object.
    Set cnn = New ADODB.Connection
    With cnn
        .Provider = "Microsoft.Jet.OLEDB.4.0"
    'Indsæt databasenavn
        .Open "C:\salesDB.mdb"
    End With

    ' opret Command objectet.
    Set cmd = New ADODB.Command
    Set cmd.ActiveConnection = cnn
    With cmd
        .Properties("Jet OLEDB:Stored Query") = True
        'Indsæt navnet på parameterqueryen
        .CommandText = "MyParamQuery"
    End With
   
    ' Execute the Command, passing in the values for the parameters.
    Set rst = New ADODB.Recordset
    'Indsæt parameteren
    Set rst = cmd.Execute(Parameters:="VIC")
       
    With rst
        Do While Not .EOF
            For Each fld In .Fields
                Debug.Print fld.Value & ";";
            Next
            Debug.Print
            .MoveNext
        Loop
   
        'Luk Recordset objectet.
        .Close
    End With
   
    ' Luk og sluk.
    cnn.Close
   
    Set rst = Nothing
    Set cnn = Nothing
   
End Sub

niels -> hvis du selv har løst problemet, så luk lige spm.

lukker spørgsmål!

spørgsmål lukket!