Sammenlign og kopier filer og mapper

Måske noget i stil med følgende.
Du gemmer det i en bat fil og kører det med følgende parametre:

1: Navnet på drev 1, f.ex c: (men ikke \\PC1)
2: Navnet på drev 2, f.ex d: (men ikke \\PC2)
3: Navnet mappen, f.ex \DOCS, brug "" hvis der er mellemrum, f.ex "\Temp Folder".

Husk at lave backup inden du slipper det løs på rigtige filer.

@echo off
setlocal

if [%1]==[] call :Usage %0 & goto :eof
if [%2]==[] call :Usage %0 & goto :eof
if [%3]==[] call :Usage %0 & goto :eof

set Drive1=%1
set Drive2=%2
set Folder=%3

for /F "delims=;" %%I in ('dir /S /B /A-D %Drive1%%Folder%\*.* 2^>nul') do call :CheckMove "%%I" %Drive2%
for /F "delims=;" %%I in ('dir /S /B /A-D %Drive2%%Folder%\*.* 2^>nul') do call :CheckMove "%%I" %Drive1%
endlocal
goto :eof

:CheckMove

set NewPath=%~1
set NewPath=%2%NewPath:~2,1024%
if exist "%NewPath%" goto :eof
call :CheckCreateDir "%NewPath%"
echo Copy %1 to "%NewPath%"
copy %1 "%NewPath%"
goto :eof

:CheckCreateDir
if exist "%~dp1\." goto :eof
echo Creating %~dp1
md "%~dp1"
goto :eof

:Usage
echo Usage: %1 Drive1 Drive2 Folder
echo Eg. %1 c: d: "\Temp Folder"

donkulk> dvs. du har ikke nogen nye version af de filer der eksister i forvejen så du ikke resikere at fil1 på A er nyere end den på B?