Hvordan laver man et script

;The '@' in the on text event will make sure only to react to the advert if you are op on the channel.
;Remember to type your own channel in the event instead of '#Your_Channel'.

on @*:TEXT:*:#Your_Channel:{
  ;In most cases you dont want a script like this to effect other ops.
  ;Here we make sure that the user is not an op on your channel before even thinking about punishing him.
  ;If it should count for everyone in the channel remove the line and a '}' from the end.
  if ($nick !isop $chan) {
    ;We check if theres is the main advert letter '#' in the users message.
    if ($chr(35) isin $strip($1-)) {
      ;Then we make sure that the advertisement is not your own channel.
      var %a 1,%ads = 0
      while ($matchtok($strip($1-),$chr(35),%a,32)) {
        if ($ifmatch != $chan) {
          ;Foreach of the channels in the message which is not your channel we increase a variable to keep track of advertisements.
          inc %ads 1
        }
        inc %a
      }
      ;Only if there actually was some hostile advertisements in the message we should go on.
      if (%ads > 0) {
        ;We keep track of the advertisements the nick has done so that we can warn/kick/ban customly.
        inc %ads. $+ $nick 1
        ;if this is the users first advertisement we only warn him.
        if (%ads. [ $+ [ $nick ] ] == 1) {
          .notice $nick The system registrered an advert in your message. That is not allowed in $chan $+ . Consider this a warning.
        }
        ;next time the users does it we get more agressive...
        if (%ads. [ $+ [ $nick ] ] == 2) {
          kick $chan $nick You where told not to advertise, but you did it again.
        }
        ;Now, if the users keeps advertising... he will be banned.
        if (%ads. [ $+ [ $nick ] ] == 3) {
          ;we choose to ban for 10 minuts or 600 seconds.. thats the -u600
          ;the last number is the address identfier.. we choose 3 to ban him regardless of dynamic ip. Syntax: *!*user@*.host
          ban -u600 $chan $nick 3
          kick $chan $nick You where warned twice until the point of no return. (10min. ban!)
          ;we start his 'personal statistics' all over...
          unset %ads. [ $+ [ $nick ] ]
        }
      }
    }
  }
}

Med kommentarer osv.. udfra det burde du godt kunne lave det.

tak skal du have. vil se om jeg kan finde ud af det.

er ret dårlig til det men hvor skal jeg sætte det ind henne det du har skrevet til mig jeg mener det er i remote.. men er ikke sikker

Ja remote