Autoluk af Excel

sættes i ThisWorkbook modul

Private Sub Workbook_Open()
Call LukTid
End Sub

Sættes i hver ark modul

Private Sub Worksheet_Change(ByVal Target As Range)
Call LukTid
End Sub

Sættes i selvstændig modul

Sub Luk()
    ActiveWorkbook.Save
    ActiveWindow.Close
End Sub

Public Sub LukTid()
Application.OnTime TimeValue(Now() + TimeValue("00:15:00")), "Luk" ' lukker om 15 min fra nu.
End Sub

Nb. har ikke testet på flerbruger, så jeg ved ikke om den lukker på alle.

Kabbak -> måske en detajle, men hvs du kører luktid fra Workbook_Open, skal du så ikke annulere den OnTime du satte der, når du kører Worksheet_Change.
(vil regnearket ikke ellers lukkes efter 15 min. uanset om der arbejdes eller ej ??)

luktid fra Workbook_Open gør at den lukker, hvis der ikke er sket noget i 15 min.

Luktid fra Worksheet_Change, gør at hver gang der er en ændring sættes OnTime til nu + 15 min

Ikke helt enig kabbak, en ny OnTime sletter ikke (automatisk) en gammel, men giver 2 stk ontime, der begge kører.

Jeg ville gøre sådan:

Disse 2 Sub's indsættes begge i ThisWorkBook
Private Sub Workbook_Open()
'1. lukketid
LukkeTid = Now + TimeValue("00:10:00")
'Sæt 1. lukketid ind i OnTime
Application.OnTime LukkeTid, "LukFil"
End Sub

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
'Annullerer forrige OnTime
If LukkeTid > 0 Then Application.OnTime LukkeTid, "LukFil", , False
'Sæt nu lukketid
LukkeTid = Now + TimeValue("00:10:00")
'sæt ny OnTime
Application.OnTime LukkeTid, "LukFil"
End Sub


og Denne i et standard modul

Public LukkeTid  'Global variabel til at holde forrige ontime

Sub LukFil()
LukkeTid = 0
'Gem og luk filen
ThisWorkbook.Close savechanges:=True
End Sub

Jeg har altid troet at en ny OnTime slettede den gamle, har du noget info herom.

Det troede jeg såmænd også en gang, indtil jeg kom til at sætte den ind i en større løkke :-)

Info: Nej
Erfaring : Ja :-)

Hov.. Jeg glemte lige at skrive at når man vil annulere en OnTime skal man bruge nøjagtig det samme klokkeslet og MakroNavn til dette.
Det er derfor at jeg bruger den globale variabel LukkeTid til at holde forrige tid/klokkeslet i.
False er afbryderen.

Application.OnTime LukkeTid, "LukFil", , False

Jeg kan ikke få det til at virke.
Udløbstiden er fra man åbner filen, ændringer har ikke indflydelse på tiden.

Jeg har forsøgsvis lagt følgende kode i en command button. Det kunne jo være at jeg havde lagt koden det forkerte sted, så jeg syntes lige det skulle afprøves.
Private Sub CommandButton1_Click()
If LukkeTid > 0 Then Application.OnTime LukkeTid, "LukFil", , False
LukkeTid = Now + TimeValue("00:15:00")
Application.OnTime LukkeTid, "LukFil"
End Sub
Aktivering af knappen, ændre heller ikke på tiden.

Hvad kan der være galt?.

Tillægs spørgsmål.
Kan man overfører lukketiden til en celle eller en tekstbox?.
Hvad er koden for at åbne en workbook?.

Kan man overfører lukketiden til en celle eller en tekstbox?.
Sheets("Ark1").Range("A1") = "Lukker Kl." & LukkeTid
Tekst1.tekst = LukkeTid

Åbne en fil ( Workbook )

Workbooks.Open Filename:="C:\Div excel\1205.xls"

Det med at åbne en workbook fungerer fint. Jeg havde tænkt mig at lave en workbook med tekst, der gør opmærksom på at de er blevet smidt af.

Hvor skal jeg placerer koden for at vise lukketid, skal det have sit eget modul?.

Disse 2 Sub's indsættes begge i ThisWorkBook
Private Sub Workbook_Open()
'1. lukketid
LukkeTid = Now + TimeValue("00:10:00")
'Sæt 1. lukketid ind i OnTime
Application.OnTime LukkeTid, "LukFil"
call Besked
End Sub

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
'Annullerer forrige OnTime
If LukkeTid > 0 Then Application.OnTime LukkeTid, "LukFil", , False
'Sæt nu lukketid
LukkeTid = Now + TimeValue("00:10:00")
'sæt ny OnTime
Application.OnTime LukkeTid, "LukFil"
call Besked
End Sub


og Denne i et standard modul

Public LukkeTid  'Global variabel til at holde forrige ontime

Sub LukFil()
LukkeTid = 0
'Gem og luk filen
ThisWorkbook.Close savechanges:=True
End Sub

Sub Besked()
' skriver lukketiden i Ark1 celle A1, ret selv
Sheets("Ark1").Range("A1") = "Lukker Kl." & LukkeTid' hvis du vil vise det i en celle
End Sub

nb. jeg har føjet en sub mere til din kode bak, og kaldt den fra de andre

Så virker det hele. Jeg havde glemt Public Lukketid, et væsentligt stykke kode.

Overførsel af lukketiden til en celle virker også, lige som jeg spurgte om. Det var nu en nedtælling jeg havde i tankerne, men det kunne jeg jo bare have skrevet.

Bak: altid rart med et vågent øje, der holder øje med tingene. Hvis du lægger et svar, så kan i få 30 point hver.

Kabbak: hvis ikke du har gættet det, skal det bruges til turnusplanen, som du tidligere har hjulpet med. Planen for fremtiden, er at lave turnusplanen som en web side. Så hvis du også er skrap til hjemmeside programering, så kan du tjene lidt flere point ved at svare på de samme spørgsmål igen, dog i et andet forum.

Jeg har forsøgt mig med følgende kode.

Sub Besked()
Do
Sheets("Sheet1").Range("A1") = LukkeTid - Now
Loop
End Sub

Så går Excel helt i selvsving. Der kommer ganske vist en nedtælling i celle A1, men der kommer også timeglas i stedet for markøren, så man ikke kan foretage sig noget.

Hvad går der galt?.
Hvordan kommer man ind i Visual Basic når Excel er gået i selvsving?.

du stopper den med Ctrl+Break
Selvsving er når en kode køre hele tiden.

Nb, jeg har ikke forstand på hjemmeside programmering, desværre.

Sub Besked()
'Do
Sheets("Sheet1").Range("A1") = LukkeTid - Now
'Loop det er her den går i selvsving den bliver aldrig færdig.
End Sub

I stedet for det loop jeg har lavet til nedtællingen, hvad kunne jeg så bruge?.
Skal det laves så den kun loopér hver sekund, eller er det noget helt andet jeg skal have fat i?.

tonny-> kabbak har fortjent dem alle for at have hjulpet dig helt i mål... :-)

Som befalet, Kabbak for alle pointene.

Tak til jer begge to, for hjælpen.

selv tak Tonny , det er noget af et projekt du er i gang med ;-)