Graf i access?

Ja man kan lave de samme grafer i Access som i Excel, da det er det samme "underporgram" de benytter sig af. I formualr desing skal du valege insert(indsaet?) menuen og der skulle chart/diagram vaere tilgangelig.
Grafen kan eksporteres som et billede (jpg, bmp osv).

Okay, det lyder godt. Så er det vel nemt nok at sætte ind på et website.

Er det mon også muligt at f.eks. redigere i dataen på databasen online (ASP), og online generere en ny jpg? Tricky!? Jeg må nok vente lidt med den funktion, men det første har stor interesse. Så kan man bruge en online upload funktion til at få billedet op på siden med.

Jeg ved at det er muligt direkte fra access, men kender ikke saa meget til ASP. Mne her en en eksempel-kode for hvordan jeg har lagt koden for at eksportere fra en command-button i access. Jeg ved ikke om det vil vaere muligt at sende lignenede instruktioner fra ASP, men det burde kunne lade sig goere:

Dim strFileName As String
Dim lngFlags As Long
Dim WebChart As Object
Dim fejl As Boolean
On Error GoTo err_msg
Set WebChart = Me.WebGraph
fejl = True
strFileName = ahtCommonFileOpenSave(Flags:=lngFlags, InitialDir:="C:\", _
        Filter:="JPEG", FilterIndex:=1, DefaultExt:="jpg", FileName:="MyGraph", _
        DialogTitle:="Save the Graph", OpenFile:=False)

WebChart.export strFileName, "jpg"
fejl = False
If fejl Then
err_msg:
MsgBox "Graph could not be exported! " & err.Description, vbOKOnly, "Error"
End If

Efterfulgt af en kode jeg fandt paa http://www.mvps.org/access/api/api0002.htm

Function ahtCommonFileOpenSave( _
            Optional ByRef Flags As Variant, _
            Optional ByVal InitialDir As Variant, _
            Optional ByVal Filter As Variant, _
            Optional ByVal FilterIndex As Variant, _
            Optional ByVal DefaultExt As Variant, _
            Optional ByVal FileName As Variant, _
            Optional ByVal DialogTitle As Variant, _
            Optional ByVal hwnd As Variant, _
            Optional ByVal OpenFile As Variant) As Variant
' This is the entry point you'll use to call the common
' file open/save dialog. The parameters are listed
' below, and all are optional.
'
' In:
' Flags: one or more of the ahtOFN_* constants, OR'd together.
' InitialDir: the directory in which to first look
' Filter: a set of file filters, set up by calling
' AddFilterItem. See examples.
' FilterIndex: 1-based integer indicating which filter
' set to use, by default (1 if unspecified)
' DefaultExt: Extension to use if the user doesn't enter one.
' Only useful on file saves.
' FileName: Default value for the file name text box.
' DialogTitle: Title for the dialog.
' hWnd: parent window handle
' OpenFile: Boolean(True=Open File/False=Save As)
' Out:
' Return Value: Either Null or the selected filename
Dim OFN As tagOPENFILENAME
Dim strFileName As String
Dim strFileTitle As String
Dim fResult As Boolean
    ' Give the dialog a caption title.
    If IsMissing(InitialDir) Then InitialDir = CurDir
    If IsMissing(Filter) Then Filter = ""
    If IsMissing(FilterIndex) Then FilterIndex = 1
    If IsMissing(Flags) Then Flags = 0&
    If IsMissing(DefaultExt) Then DefaultExt = ""
    If IsMissing(FileName) Then FileName = ""
    If IsMissing(DialogTitle) Then DialogTitle = ""
    If IsMissing(hwnd) Then hwnd = Application.hWndAccessApp
    If IsMissing(OpenFile) Then OpenFile = True
    ' Allocate string space for the returned strings.
    strFileName = Left(FileName & String(256, 0), 256)
    strFileTitle = String(256, 0)
    ' Set up the data structure before you call the function
    With OFN
        .lStructSize = Len(OFN)
        .hwndOwner = hwnd
        .strFilter = Filter
        .nFilterIndex = FilterIndex
        .strFile = strFileName
        .nMaxFile = Len(strFileName)
        .strFileTitle = strFileTitle
        .nMaxFileTitle = Len(strFileTitle)
        .strTitle = DialogTitle
        .Flags = Flags
        .strDefExt = DefaultExt
        .strInitialDir = InitialDir
        ' Didn't think most people would want to deal with
        ' these options.
        .hInstance = 0
        '.strCustomFilter = ""
        '.nMaxCustFilter = 0
        .lpfnHook = 0
        'New for NT 4.0
        .strCustomFilter = String(255, 0)
        .nMaxCustFilter = 255
    End With
    ' This will pass the desired data structure to the
    ' Windows API, which will in turn it uses to display
    ' the Open/Save As Dialog.
    If OpenFile Then
        fResult = aht_apiGetOpenFileName(OFN)
    Else
        fResult = aht_apiGetSaveFileName(OFN)
    End If

    ' The function call filled in the strFileTitle member
    ' of the structure. You'll have to write special code
    ' to retrieve that if you're interested.
    If fResult Then
        ' You might care to check the Flags member of the
        ' structure to get information about the chosen file.
        ' In this example, if you bothered to pass in a
        ' value for Flags, we'll fill it in with the outgoing
        ' Flags value.
        If Not IsMissing(Flags) Then Flags = OFN.Flags
        ahtCommonFileOpenSave = TrimNull(OFN.strFile)
    Else
        ahtCommonFileOpenSave = vbNullString
    End If
End Function