Uendelig løkke

objRS.moveFirst
      while not intCurrent = 999999
        While Not objRS.EOF
          if objRS("id") = intCurrent then
            intCurrent = objRS("parent")
            Redim Preserve arrPath(intCount+1)
            arrPath(intCount) = objRS("name")
            intCount= intCount + 1
          end if
          objRS.MoveNext
        Wend
      wend

Jeg ville gætte på en stavefejl.
Kontroller at den intCurrent du sætter til 2 er stavet rigtigt.

umiddelbart ser det ud til at være stavet rigtigt, og med hensyn til at flytte objRS.moveFirst, vil det ikke løse problemet, da vi ønsker at køre recordsettet igennem indtil intCurrent=999999, dvs vi skal starte forfra flere gange.

Jeg lavede lige en lille test med:
intCurrent=2
intCount=0
Dim arrpath()
      while not intCurrent = 999999
        objRS.moveFirst
        While Not objRS.EOF
          if objRS("id") = intCurrent then
            intCurrent = objRS("parent")
            Redim Preserve arrPath(intCount+1)
            arrPath(intCount) = objRS("name").Value
            intCount= intCount + 1
          end if
          objRS.MoveNext
        Wend
      wend
for i=lbound(arrPath) to ubound(arrPath)
  Response.Write "<br>" & arrPath(i)
next

Og det kører uden problemer

Det kunne selvfølgelig også være noget andet på siden.

Prøv at sætte en tæller ind som stopper den.

i=0
      while not intCurrent = 999999 and i<10
        objRS.moveFirst
        While Not objRS.EOF
          if objRS("id") = intCurrent then
            intCurrent = objRS("parent")
            Redim Preserve arrPath(intCount+1)
            arrPath(intCount) = objRS("name").Value
            intCount= intCount + 1
          end if
          objRS.MoveNext
        Wend
    i=i+1
      wend
Response.Write i

ok, jeg tror i er nødt til at se hele koden:

<%
  dim strQ, objRS, intUndock, strPath, intCurrent, arrPath(), intCount, intI

  Function listCategories()
    strQ = "SELECT * FROM categories ORDER BY name"
    Set objRS = objConnect.Execute(strQ)
   
    intUndock = request.QueryString("undock")

    intCount = 0
    if not intUndock="" then
      intCurrent = intUndock
      while not intCurrent = 999999
        objRS.moveFirst
        While Not objRS.EOF
          if objRS("id") = intCurrent then
            intCurrent = objRS("parent")
            Redim Preserve arrPath(intCount+1)
            arrPath(intCount) = objRS("name")
            intCount= intCount + 1
          end if
          objRS.MoveNext
        Wend
      wend
      For intI=ubound(arrPath) to lbound(arrPath) Step -1
        response.write(arrPath(intI) & "<br>")
      next
    else
      intUndock = 999999
    end if

    objRS.moveFirst
    While Not objRS.EOF
      if objRS("parent") = intUndock then
        response.write(objRS("id") & " - " & objRS("name") & " - " & objRS("parent") & " - " & objRS("creator") & " - " & objRS("created") & " - " & objRS("description") & " - " & objRS("public") & "<br>")
      end if
      objRS.MoveNext
    Wend

    objRS.close
    Set objRS = Nothing
  end Function
%>

Hvis der ellers er nogen der kan overskue det problem vi forsøger at løse ved hjælp af denne kode, må i meget gerne komme med helt andre forslag til hvordan det kan gøres! :-)

intCurrent starter ikke som et tal, så den vil aldrig være lig indholdet af feltet.

intUndock = request.QueryString("undock")
if IsNumeric(intUndock) then
  intUndock=cLng(intUndock)
else
  intUndock=0
end if
intCount = 0
if intUndock<>0 then
    intCurrent = intUndock
    while not intCurrent = 999999

I finder tilsyneladende frem til en posts position i et hieraki.
Det er en noget tung metode i bruger til det.

Hvilken database skal det køre på?

Så er problemet løst, det var bare lidt string/integer forvirring.

løsningen var at skrive

    intUndock = Int(request.QueryString("undock"))
i stedet for
    intUndock = request.QueryString("undock")

Tak for hjælpen;-)

ps. mortrr hvis du lige tilføjer et svar kan du få lidt point som tak for hjælpen.

Det skal køre på en mySQL database.

Har du en nemmere måde at gøre det på?

Vi så ikke dit svar før vi fandt vores løsning, men du har da fuldt ud fortjent pointene, så hvis du lige skriver et svar er de dine.

mySQL har det ikke godt med sub-selects, og understøtter ikke stored-procedures/triggers (endnu), så den eneste anden løsning ville være at lave en længere række selects.
Du kan dog få det til at gå en del hurtigere ved kun at udvælge præcis de felter du skal bruge, i stedet for bare *.