Søge på flere værdier fra en liste

Du bliver nok lige nødt til at udspecificere lidt.... hvad er det til? hvad hedder tingene? mm..

jEg formoder det er noget lig dette her.. se mit svar på dette spørgsmål..

http://www.eksperten.dk/spm/29459

Jeg prøver lige igen. Jeg har oprettet en liste i en ubundet formular og har angivet, at det skal være muligt at markere flere værdier på listen. Det har jeg gjort med egenskaben \"FlereMarkeringer\" sat til \"sammensat markering\".

Når jeg bagefter skal udforme en forspørgsel kan jeg ikke finde ud af at referere til de markerede værdier. Jeg kan jo ikke bruge Forms![Min formular].[navnet på min kombinationsboks]

Der må jeg desværre melde pas. :-(
Jeg kender ikke noget til den funktion (markere flere), og kunne heller ikke finde den.

Så vidt jeg ved kan du ikke refererer til flere værdier i det samme kriteriefelt i din query, med mindre du har en \"eller\" funktion med i udtrykket. Og jeg tror ikke at din sammensatte markering genererer et eller udtryk mellem dine valgte parametre. eg. :

værdi 1
værdi 2

Sådan gør vi så, når vi vasker ...

Mit eksempel:

Du har en tabel \"Table2\", som indeholder:
Dag as String, Tid as Date/Time
Tabellen udfylder du med Mandag, Tirsdag.... sammen med nogle tilfældige klokkeslet.


Du har en Original Query \"Original XXX\", som vil vise alle data:
SQL = \"SELECT Table2.Dag, Table2.Tid
FROM Table2;\"

Så har du en kopi af denne Query \"XXX\". Den bliver der hele tiden lavet nye kriterier på, men hver gang med udgangspunkt i din original.

Så har du en Form med en listbox \"List2\", som har sat funktionen MultiSelect er sat til Extended.
På formen har du ligeledes en knap \"DoIt\", som skal have følgende event:

Private Sub DoIt_Click()
On Error GoTo Err_DoIt_Click

    Dim TempSource, BasisSource As String
    Dim Cnt As Integer, FirstCriteria As Boolean
   
    BasisSource = CurrentDb.QueryDefs(\"Original XXX\").SQL
   
    TempSource = \"\"
    FirstCriteria = True
    With Me.List2
        For Cnt = 0 To .ListCount - 1
            If .Selected(Cnt) Then
                If FirstCriteria Then
                    FirstCriteria = False
                    TempSource = \" WHERE (\"
                Else
                    TempSource = TempSource & \") OR (\"
                End If
                TempSource = TempSource & \"[Dag] = \'\" & .Column(0, Cnt) & \"\'\"
            End If
        Next
    End With
    If TempSource <> \"\" Then TempSource = TempSource & \")\"
   
    CurrentDb.QueryDefs(\"XXX\").SQL = Left(BasisSource, Len(BasisSource) - 3) & TempSource
    \'MsgBox Left(BasisSource, Len(BasisSource) - 3) & TempSource

    DoCmd.OpenQuery \"XXX\"

Exit_DoIt_Click:
    Exit Sub

Err_DoIt_Click:
    MsgBox Err.Description
    Resume Exit_DoIt_Click
   
End Sub


Den der MultiSelect parameter laver ikke andet end at give dig mulighed for:

- kun at kunne vælge ét linie
- at kunne vælge et tilfældigt antal linier fra og til ved blot at klikke på dem
- at kunne vælge et tilfældigt antal linier fra og til på ganske almindelig Windows manér med Ctrl og Shift.

Resultatet af det hele er, at du får trukket de linier ud i din Query, som du vælger i din ListBox.

Og det virker - for jeg har testet det i Windows NT 4.0 Servicepack 5, MS Office 2000 Premium edition på en Compaq Deskpro SFF6450 under normal belysning og med nye nedrulningspersienner i alle tre vinduer (montørerne er stadigvæk ved at pakke emballage væk - så nye er de).

Det virker kanon også selvom jeg sidder ved en meget støvet og forældet maskine ;-). Tusind tak!

Fint - tak