Erstatte "AND"/"OR" i streng

Hvilket sprog, perl, PHP, Javascript, ASP eller noget femte?

ASP

Havde du evt. en løsning?

Det tog lidt længere tid end jeg først havde forventet, desværre nok fordi det er ASP. Funktionerne omkring regulære udtryk i ASP har et antal besværlige begrænsninger hvoraf de vigtigste er: Med Execute kan man ikke bruge paranteser til at opsamle del-strenge fra den matchede streng, dette kan man godt med Replace, men til gengæld gælder Global ikke i Replace. Jeg har valgt en 2-skridt løsning, hvor jeg først finder alle delstrenge omsluttet af ", derefter erstatter jeg AND i hver af disse med hvad der nu måtte ønskes. Det ser således ud:

Function ReplaceWithinQuotes( str, toreplace, replacement )
  Dim result
  Dim regEx                    ' Create variables.
  dim Matches
  dim NextIndex
  dim quoteStr


  Set regEx = New RegExp              ' Create regular expression.
  regEx.Pattern = """[^""]*"""  ' Set pattern.
  regEx.IgnoreCase = True              ' Make case insensitive.
  regEx.Global = True
  result = ""
  count = 1
  Set Matches = regEx.Execute(str)


  if Matches.Count = 0 then
      result = str
  else
      NextIndex = 1
      For Each Match in Matches
        result = result & mid(str, NextIndex, Match.FirstIndex-NextIndex+1)
        quoteStr = Match.Value

        result = result & Replace( quoteStr, toreplace, replacement )
        NextIndex = Match.FirstIndex + Len(quoteStr) + 1
      Next
      result = result & mid(str, NextIndex)
  end if

  ReplaceWithinQuotes = result
End Function

Den kaldes fx således:

  str = "plihi AND plaha""Søren AND Peter"" AND ""Ole OR Niels"" AND ""bla AND BLI""blaha AND blaha"
  result = ReplaceWithinQuotes( str, "AND", "noget" )


Mvh
Jesper Naur

Det ser rigtig spændende ud. Jeg kigger lige på det og vender snart tilbage.

Det virkede rigtig fint... tak for hjælpen

Kan du evt. fortælle mig hvad følgende udtryk betyder: "[^"]*"

Det betyder:
1 stk gåseøjne efterfulgt af 0 eller flere 'ikke-gåseøjne' efterfulgt af 1 stk gåseøjne.