IIS -> Exchange (SMTP relay)

Som der står "Permission denied", Det må være noget rettighedssnask, e.v.t. for IISUser_servernavn

bufferzone har sandsynligvis ret, det har noget med rettigheder at gøre.

Hvis du har Service Pack 3 på din Exchange server, kan du sikkert finde løsningen her: http://support.microsoft.com/default.aspx?scid=KB;EN-US;Q324037&

Tak - umiddelbart tror jeg at jeg vil prøve forslag 3 i microsoft artiklen.

Det at ændre krav til kodning er fint nok for os fremfor af ændre på de generelle rettigheder eller har det ikke nogen praktisk betydning at lave de rettigheder om - er det tilbage til før sp3 så sikkerhedsproblematikken bare ingoreres?.

Er der nogen der har praktiske erfaringer i denne problematik?

/AndersF

Hej

Jeg bruger dette script, til at tilføje IUSR_xx:

-------------------------------------------------------------------------------
'This script adds an access control entry (ACE) for a specified account with Read and Enumerate rights to all SMTP service instances.
'To use this script, run the following command at a command prompt:
'cscript mbaadd.vbs <ComputerName>\<AccountName>

    Option explicit
    Dim objSMTP, objInst, objSD, objACL, objACE, objNew
    Dim sAccount

    sAccount = wscript.arguments(0)
    wscript.echo "Updating SMTP service instances..."
    Set objSMTP = GetObject("IIS://LOCALHOST/SMTPSVC")

    For Each objInst In objSMTP
      If objInst.class = "IIsSmtpServer" Then
          wscript.echo objInst.ADSPath
          set objSD = objInst.AdminACL
          set objACL = objSD.DiscretionaryACL
          set objNew = CreateObject("AccessControlEntry")
          objNew.AccessMask = 9 ' read + enumerate
          objNew.AceType = 0 ' ADS_ACETYPE_ACCESS_ALLOWED
          objNew.AceFlags = 2 ' ADS_ACEFLAG_INHERIT_ACE
          objNew.Trustee = sAccount

          objACL.AddAce objNew
          objSD.DiscretionaryACL = objACL
          objInst.Put "adminACL", Array(objSD)
          objInst.SetInfo
      End If
    Next
-------------------------------------------------------------------------------

Sikkerheden bliver selvfølgelig lavere, men er stadig bedre end med SP2.

Jeg sidder og kan bare ikke finde et script der ikke kræver ændringer af rettigheder.
Cdonts, Cdosys ved brug af port 25 eller pickup virker bare ikke når jeg ligger ud på vores offentlige Webserver men fint på LAN IIS.

/AndersF

Så lykkes det at lave et script med cdosys der virker uden at ændre på rettighederne.
Mange tak
/AndersF

Hvad gjorde du?

Jeg bruger Cdosys (port 25)- det virker fint
/AndersF

<%@ Language=VBScript %>
<%
    Dim iMsg
    Dim iConf
    Dim Flds
    Const cdoSendUsingPort = 2
    Const strSmartHost = "yourservername.com"

    'Create the message object.
    Set iMsg = CreateObject("CDO.Message")

    'Create the configuration object.
    Set iConf = iMsg.Configuration

    'Set the fields of the configuration object to send by using SMTP through port 25.
    With iConf.Fields
      .item("http://schemas.microsoft.com/cdo/configuration/sendusing") = cdoSendUsingPort
      .item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = strSmartHost
      .Update
    End With

    'Set the To, From, Subject, and Body properties of the message.
    With iMsg
      .To = "mbaker@adatum.com"
      .From = "mbaker@adatum.com"
      .Subject = "Test message by using CDOEx and cdoSendUsingPort, sent on: "  & now()
      .TextBody = "This is a test by using CDOEx"
      .Send
    End With
    set iMsg = Nothing
%>

Jeg har det her script, kan du lave det om til cdosys for mig??
' CDONTS Mail Object

    set mail = Server.CreateObject("CDONTS.NewMail")
    mail.From = sender_address
    mail.To = recipient_address
   
    mail.Subject = subject
    mail.Body = body
       
    '' optional settings
    'mail.CC = "one@domain.com;two@domain.com"
    'mail.BCC = "blind@domain.com"
    'mail.Importance = 1 '(0=Low, 1=Normal, 2=High)
    'mail.AttachFile "c:\path\filename.txt", "filename.txt"
    'mail.AttachURL = ' Usage unkown.
    mail.BodyFormat = 0 ' HTML or '1' for plain text (default)
    mail.MailFormat = 0 ' MIME or '1' for plain text (default)
   
    '' send the mail
    on error resume next
    mail.Send
    if err.number = 0 then
        sendmail = 1
    else
        sendmail = -1
    end if
    on error goto 0

    end select
       
end function