Hent tekst fra .txt og Skriv efter ord

Du kan læses fra en fil og udskriver det hele på en gang..:


Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
'Åbner filen for læsning.
Set file = objFSO.OpenTextFile("C:\SomeFile.txt", 1)

'Udskriver hele tekst filen
Response.Write file.ReadAll

file.Close
Set file = Nothing

man kan evt læse en linie af gangen og skrive den i en kolonne:

Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
'Åbner filen for læsning.
Set file = objFSO.OpenTextFile("C:\SomeFile.txt", 1)

response.write "<table><tr>"

do while not file.atEndOfStream
  response.write "<td>"
  'Udskriver file linie for linie
  Response.Write file.ReadLine
  response.write "</td>"
loop
response.write "</tr></table>"

file.Close
Set file = Nothing

hvis du vil skrive ord for ord i hver kolonne skal du læse linie/det heel og så slite op og skrive det i hver sin kolonne eks;


Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
'Åbner filen for læsning.
Set file = objFSO.OpenTextFile("C:\SomeFile.txt", 1)
'Læs hele filen
strFile = file.ReadAll
'Split linien op ved mellemrum
strArr = Split(strFile," ")

response.write "<table><tr>"

for i = lbound(strArr) to ubound(strArr)
  response.write "<td>"
  'Udskriv et ord.
  Response.Write strArr(i)
  response.write "</td>"
next
response.write "</tr></table>"

file.Close
Set file = Nothing

Ah ok :)

Men ser du .. txt filen ligger ikke på min server.. det sidste virkede ret præcist :) men den er et andet sted ö

Hvordan har du adgang til txt-filen ??

ftp - http - netværk eller ......

http :)

Filen ligger på en anden server :)

Har du nogen komponenter installeret på asp-serveren (ASPhttp osv..) ??

For så kan du lave noget ala det her:

Set HttpObj = CreateObject("AspHTTP.Conn")
HTTPObj.Url = "http://www.xxxx.dk/SomeFile.txt"
HTTPObj.RequestMethod = "GET"
strResult = HTTPObj.GetURL

'Split linien op ved mellemrum
strArr = Split(strResult," ")

response.write "<table><tr>"

for i = lbound(strArr) to ubound(strArr)
  response.write "<td>"
  'Udskriv et ord.
  Response.Write strArr(i)
  response.write "</td>"
next
response.write "</tr></table>"

njjj