Makroknap, der sender Worddok. som vedhæftet mail

Prøv evt. at se på dette link, hvor der er en opskrift på at sende via Outlook Automation, men det kræver af afsender gemmer dokumentet først og altså bruger Outlook.

http://www.mvps.org/word/FAQs/InterDev/SendMail.htm

Ved brug af routing slip (som også er beskrevet) behøver dokumentet ikke at være gemt først og det kræver ikke et bestemt email program.

Vil det sige, at du ikke har en alternativ løsning til mit behov ? Kræver Exchange-Outlook at det kører via distrib. lister ?

Jeg vil lige "kigge i bøger" i aften, når jeg kommer hjem. Jeg vender tilbage i morgen.

Her er den fulde kode inkusiv svaret på dine spørgsmål *S*

Sub SendDocumentAsAttachment()

Dim bStarted As Boolean
Dim oOutlookApp As Outlook.Application
Dim oItem As Outlook.MailItem

On Error Resume Next

If Len(ActiveDocument.Path) = 0 Then
    MsgBox "Document needs to be saved first"
    Exit Sub
End If


Set oOutlookApp = GetObject(, "Outlook.Application")
If Err <> 0 Then
    Set oOutlookApp = CreateObject("Outlook.Application")
    bStarted = True
End If

Set oItem = oOutlookApp.CreateItem(olMailItem)

oItem.Importance = olImportanceHigh
With oItem
    .To = "rvejemad@sca.csc.com"
    .Subject = "Test 2"
    'Add the document as an attachment, you can use the .displayname property
    'to set the description that's used in the message
    .Attachments.Add Source:=ActiveDocument.FullName, Type:=olByValue, _
      DisplayName:="Document as attachment"
      .Importance = olImportanceHigh ' Vigtighed = høj
      .ReadReceiptRequested = True ' Sender en mail tilbage, når denne mail er blevet læst
    .Send
End With

If bStarted Then
    oOutlookApp.Quit
End If

Set oItem = Nothing
Set oOutlookApp = Nothing

End Sub

Jeg kan se, at rvm var hurtigere end mig. Sådan går det, når man arbejder om aftenenen :-)

Vi kommer åbenbart ikke nærmere løsningen, så jeg har delt point mellem jer, da den løsning som rvm beskriver, faktisk også er beskrevet på den webside som jkrons henviser til. jeg takker for indsatsen :)

Den løsning jeg viste er almen kendt, men svaret på dit spørgsmål angående Importance og ReadReceiptRequested er ikke noget du kan finde på denne side...