XML via HTTP (ASP) ?

Brug ServerXMLHTTP til at hente filen med:

Set oXML = Server.CreateObject("MSXML2.ServerXMLHTTP")
oXML.Open("GET", "http://server/mappe/fil.xml", false)
oXML.Send

Herefter kan du bl.a. hente:

oXML.responseXML
oXML.responseText

/CS

Den giver følgende fejl:
Microsoft VBScript compilation (0x800A0414)
Cannot use parentheses when calling a Sub
/xmlhttp/Default.asp, line 6, column 64
XML.Open("GET", "http://servernavn/http_test.xml", false)

(stien er udskiftet med "servernavn")

PÅ basis af det du skrev, har jeg lavet følgende (som virker) så du får dine point :)

<%
Option Explicit
Dim ObjSXH, ObjXML, ObjXSL
'Using MSXML 3.0 ServerXMLHTTP Class   
Set ObjSXH = Server.CreateObject("Msxml2.ServerXMLHTTP.3.0")
'GET Request
ObjSXH.open _
  "GET", _
  "http://servernavn/http_test.xml", _
  False
'Send the request
ObjSXH.send ""
'If the request succeeded
If ObjSXH.status = 200 Then
      'returned XML as a DOMDocument
      Set ObjXML = ObjSXH.responseXML
      'Load the XSLT stylesheet
      Set ObjXSL = Server.CreateObject("Msxml2.DOMDocument.3.0")
      ObjXSL.load Server.MapPath("/xmlhttp/test.xsl")
      'Apply XSL Transformation and write the HTML result
      Response.Write (ObjXML.transformNode(ObjXSL))
Else
      Response.Write "An error occurred. Please try later."
End If%>

Hehe - jeg bruger altid JavaScript, så der havde lige sneget sig et par parenteser ind dér... :-)

/CS