Alarm ved dublet

Ét sted skriver du "over 3", et andet sted "over 5".

Jeg er gået ud fra "over 3" i denne matrixformel:

=HVIS(TÆL.HVISER($A$1:$A$7;">3")-(SUM(1/MPRODUKT((HVIS(($A$1:$A$7>3);$A$1:$A$7)=TRANSPONER(HVIS(($A$1:$A$7>3);$A$1:$A$7)))+0;RÆKKE($A$1:$A$7)^0))-1)>0;"Fejl";"")

Du kan bruge denne formel til at give en advarsel - skal dog rettes til, hvis andre værdier end 4, 5, 6 eller 7 bruges:

=IF(MAX(COUNTIF($A$1:$A$7;{4;5;6;7}))>=2;"Advarsel";"")

På dansk:
=HVIS(MAKS(TÆL.HVIS($A$1:$A$7;{4;5;6;7}))>=2;"Advarsel";"")

Desværre kan formelen ikke bruges til datavalidering, så du skal nok indsætte den i cellen ved siden af

Har du nyeste version af office 365 med de nyeste formler tilgængelig?

Jeg benytter den nyeste version af Office 365 - på dansk :)
Jeg kan se det ikke er ligetil, og min formulering af spørgsmål lader også lidt tilbage at ønske.

Jeg deler lige arket med jer her i håb om at problemet kan løses.

https://1drv.ms/x/s!ArThM-lSEJTShZQk1xQl_pmvNo-QHQ?e=KsKZfG

I fanen Skemaønsker kommer der via LOPSLAG nogle værdier i Kolonne D - Valgblok.
I C25 vil jeg gerne foretage en validering af kolonnen valgblok.

Der må ikke opstå dubletter i kolonnen valghold.

PS. I kolonnen Sum skriver den 0 når der ikke er værdier i E og F. Jeg har prøvet med diverse HVIS-formler for at få den til at skrive " ", men det er ikke lykkes mig at få det til at virke, fordi den åbenbart tror der står noget i de tomme celler - selv om det kun er en formel.

Kan også det løses?

Pfht for hjælpen!

Celle D12 referer i formlen til celle A11, er det korrekt eller en fejl?

Angående din sum kolonne, så brug noget ala nedenstående (engelsk)

=IF(SUM(E11:F11)=0;"";SUM(E11:F11))

Angående dubletter

Hvis ikke du finder anden løsning, så kan denne lidt 'tunge' metode bruges.

Lav i en kolonne en tæl.hvis formel der tæller antal forekomster i oversigten for hver linie. såfremt værdien bliver >=0 gives der en visuel advarsel.
En del af dette kan jo blot gøres med 'usynlig skrift' som du gør i D9.

Se min tilføjelse i R11 som erstatning for kolonne A

Thomas - din løsning til Sum-kolonnen er genial - tak for den.

Løsningen med den tunge metode forstår jeg ikke.

Se evt. regnearket.

Når jeg tæller antallet af forekomster pr. linje får jeg jo .. ja antallet .. men jeg forstår ikke hvad jeg kan bruge det til.

Kan du uddybe så sent på en fredag? :)

Den med antallet af forekomster er jeg heller ikke helt sikker på.
Men det er fordi jeg ikke er helt med på hvordan din validering skal tage sig ud.
Kan du evt uddybe lidt.

Se også gerne længere ud til højre hvor jeg foreslår noget mere simpelt til at hente hold oplysningerne om i oversigten.

Tilbage efter en lang og slidsom påskeferie :)

Måske har jeg ikke defineret mit problem klart nok - det beklager jeg.

I regnearket vil jeg gerne have at der i celle C25 står "FEJL" hvis der i cellerne D11:D23 optræder 2 ens værdier - som der gør nu: 19fxid-b1 optræder to gange.

Hvis ikke der optræder dubletter i cellerne D11:D23 skal celle C25 forblive tomt.

Det burde kunne lade sig gøre med:

=IF(MAX(COUNTIF($D$11:$D$23;$D$11:$D$23))>1;"Fejl";"")

Dansk:
=HVIS(MAKS(TÆL.HVIS($D$11:$D$23;$D$11:$D$23))>1;"Fejl";"")

Hej Jens,

Den virker umiddelbart - problemet er at der i D11:D23 står en formel:

=HVIS($D$9>=1;LOPSLAG($C$4;'2. Hold'!$A$5:$O$473;14;FALSK);"")

Og den returnerer et 0 hvis cellerne i kolonne 14 i fanden Hold er tom - hvilket jeg faktisk ikke helt forstår.

Derfor returnerer formelen Fejl.

Prøv at ændre formelen til

=IF(MAX(COUNTIFS($D$11:$D$23;$D$11:$D$23;D11:D23;"<>"&""))>1;"Fejl";"")

Dansk:
=HVIS(MAKS(TÆL.HVISER($D$11:$D$23;$D$11:$D$23;D11:D23;"<>"&""))>1;"Fejl";"")

Desværre med samme resultat

Den formel jeg gav i #14 virker kun hvis der er en enkelt formel i området D11:D23. Men hvid du retter din formel til

=HVIS($D$9>=1;LOPSLAG($C$4;'2. Hold'!$A$5:$O$473;14;FALSK);0)

(0 istedet for "")

og min formel til

=HVIS(MAKS(TÆL.HVISER($D$11:$D$23;$D$11:$D$23;D11:D23;"<>"&0))>1;"Fejl";"")

vil jeg mene at det virker

Hej Jens,

Det gør den også - nu står der så blot et træls 0 som udgangspunkt i D11:D23 - men jeg laver en ekstra kolonne til verificeringen skjuler den og laver en hvis-formel som siger hvis der står "fejl" i cellen med verificeringen skal den returnere "du har 2 ens valg".

1000 tak for hjælpen :)

Du kan gå ind i File - Options - Advanced - Display options for this worksheet - og fjerne fluebenet i "Show a zero in cells that have zero value". Så behøver du ikke en ekstra kolonne.