VBA opret mappe og gemsom i mappen

Hej

Prøv noget ala:

Private Sub GemSom_Click()
' laver 2 tekst-variable
Dim Sti as String
Dim FilName as Stirng

' tildeler indhold til variablene
Sti=ThisWorkbook.Path & "\" & Range("b6").Value & " " & Date
FilName=ThisWorkbook.Name

kode der danner mappen:
If Dir(Sti, vbDirectory) = "" Then
        MkDir Sti
End If

'Koden der danner filen
ThisWorkbook.SaveAs Sti & "\" & FilName

End Sub

Kanon tak for det :-)

Rettede et par stavefejl der gav en error og så filnavnet og så virker det :-)

ups, hjernen hurtigere end hånden ;-)

Måske du kan svare mig på noget nyt jeg er rendt ind i?

Efter at jeg har brugt din kode, så er det jo den nye fil der er åben. Jeg har endnu en macro der skal gemme en PDF. Den virker ikke i den nye fil før jeg har haft lukket regnearket og åbnet det igen???

tror noget ala dette vil hjælpe dig


Jan

Den laver en masse, men den danne ikke en ny mappe?

Det er meningen at den skal lave et nyt projekt som alle ark kopieres over i for derefter at gemme den mappe som derefter lukkes så du står i den oprindelige mappe, så du kan køre din makro:

Prøv denne kode ellers tror jeg ikke jeg kan knække den!!

Option Explicit
Private Sub GemSom_Click()

Dim Wb As Workbook, NewWb As Workbook
Dim Ws As Worksheet, TempWs As Worksheet

' laver 2 tekst-variable
Dim Sti As String
Dim FilName As String

' tildeler indhold til variablene
Set Wb = ThisWorkbook
Sti = ThisWorkbook.path & "\" & Range("b6").Value & " " & Date
FilName = ThisWorkbook.Name

MsgBox "Er denne sti rigtig?  " & Sti 'til test

'kode der danner mappen:
If Dir(Sti, vbDirectory) = "" Then
        MkDir Sti
End If

'Laver ny workbook og kopierer ark over
Set NewWb = Application.Workbooks.Add
Set TempWs = NewWb.Sheets(1)
For Each Ws In Wb.Sheets
    Ws.Copy before:=TempWs
Next
With Application
    .DisplayAlerts = False
        TempWs.Delete
    .DisplayAlerts = True
End With

'Koden der danner filen
NewWb.SaveAs Sti & "\" & FilName
NewWb.Close

End Sub

Du skal have mange tak for hjælpen. Jeg holder mig til første løsning. Jeg har bare lagt en Application.Quit ind til sidst. Så er brugeren tvunget til at åbne det igen hvis de ikke er færdige med at bruge det :-)

Velbekomme