År til dato i budget ark

Hej Casper

Med dine budget tal i B1:B12 kan du prøve denne i C1 og trække  ned
=IF(AND(B2="";B1<>"");SUM($B$1:B1);"")

eller dansk

=HVIS(OG(B2="";B1<>"");SUM($B$1:B1);"")

Vh
Anedi

Jeg syntes ikke lige jeg kan få det til at virke. Måske jeg ikke har forklart mig ordentligt.

Har 2 ark. Budget og balance.

I budget har jeg omsætning i A3 og værdier i B3-B12 har jeg et omsætnings tal pr måned. Jeg har en sum formel der hente omsætningstallet for den angivende måned. Fx for januar bliver januar B3 hente ind. Jeg ønsker at have en kolonne som summere de forskellige måned i et felt der hedder år til dato.

Fx januar
Periode 212                År til dato  212

Februar
Periode 160                År til dato 372

Håber det er forklaret lidt bedre.

Så prøv i C3:
=IF(B3="";"";sum($B$3:B3)

Virker den?

Og den skal naturligvis trækkes ned til celle C12

Jeg tror ikke helt at den formel du kommer med virker Anedi.

Perioden søger på kriteriet i måned og tager summen for den enkelte måned som står i samme række, omsætningen for den enkelte måned står ligeledes i samme række.

I kolonnen periode søger den ved =SUM.HVIS(B5:M5;B3;B6:M6), B5:M5 er januar til december, B3 er der hvor jeg angiver den måned som der bliver arbejdet på. Mens B6:M6 er omsætningen for den enkelte måned.

I år til dato ønsker jeg at hvis jeg tager udgangspunkt i marts at den tager summen af tidligere måneder til og med marts? Så en eller anden formel der kan sige hvis B3 = en måned i B5:M5 så skal den tage summen af månederne der ligger tidligere.

Håber denne beskrivelse giver lidt mere mening i forhold til mit problem/spørgsmål.

//Casper Andersen

Ok, med ovenstående opsætning, så prøv denne i C3:
=SUM(OFFSET(B6;0;0;1;MATCH(B3;$B$5:$M$5;0)))

Dansk:
=SUM(FORSKYDNING(B6;0;0;1;SAMMENLIGN(B3;$B$5:$M$5;0)))

Vh
Anedi

Hej

Det er super det ser ud til at fungere, så hver gang jeg ændre min måned i B3, så tager den summer fra tidligere måneder til og med den angivede måned.

Vil du have noget imod at give en kort forklaringer over hvad det er der sker i denne formel, da jeg også ønsker at lære og ikke bare finde løsningen.

Hvordan kan den fx. tage summe når der kun er angivet B6 som eneste tal?

Håber du vil hjælpe med en lille forklaring.

// Casper Andersen

Hej Casper

Det var godt det lykkedes.
Her er en lille forklaring.
Den ydre funktion er blot en sum-funktion. Den summer altså indholdet, dermed vil den også blot tage værdien i B6, hvis det er den eneste celle med tal i. (Ved ikke om det var det du mente).

OFFSET/FORSKYDNING-funktionen fungerer ved at angive en startcelle (her B6), der er den første celle i området vi er interessede i. Funktionen kan bruges til at lede efter en værdi i en celle der er et angivet antal rækker og kolonner væk. Eller den kan bruges til at udpsænde et område af flere celler. Og det er det vi gør her.
OFFSET-funktionen har fem parametre:
1) Den celle du tager udgangspunkt i (her B6)
2) Rækker: Hvor mange rækker ned skal der kigges (0 her, vi ønsker at tage udgangspunkt i celle B6)
3) Kolonner: Hvor mange kolonner til højre skal der kigges (0 her, vi ønsker at tage udgangspunkt i celle B6)
4) Højde: Hvor "højt" skal dit område være, målt i antal celler (1 angiver her, at vi bliver i række 6. Havde vi valgt to, ville området både være række 6 og 7)
5) Bredde: Hvor "bredt" skal dit område være, målt i antal celler. (Her vil vi gerne have antallet af celler til at følge nummeret på måneden du har angivet i B3).

Antallet i Bredde kan angives manuelt, hvis det altid er ens. Her bruger vi en MATCH/SAMMENLIGN-funktion, som på baggrund af en opslagsværdi (B3) søger efter hvor den værdi optræder i området B5:M5. 0'et tilsidst angiver blot at der skal være tale om et eksakt match for måneden.

Jeg håber det giver mening.

Vh
Anedi

Hej Anedi

Jeg tror det giver mening, skal lige sidde og arbejde med formlen mens jeg læser din beskrivelse. Så skal det nok giv mening.

Endnu engang tak for svaret og din forklaring så det også er forståeligt.

// Casper Andersen